Outside the sky is mercilessly bright, and the hot air full of all the varied sounds of an army ready to march; but inside this small shrine are coolness,darkness and solitude.  And peace, which is a rare and precious thing to find in these years since the Usurper placed himself upon Tsolyánu's Petal Throne, igniting a civil war.

Before you stands a statue of your god, presiding over an alter on which other legionaries have placed offerings.  There are ten gods in Tsolyánu: five who champion the cause of unchanging Stability, and five who wish to bring about endless Change.  All are permitted their temples and honored on their holy days, but you and your family, like most Tsolyáni, have a particular patron deity.  Who's face do you look into?

*choice
	#Lord Hnálla, the Illumination of All the World and supreme principal of Stability
		The hiMaróda lineage of the most aristocratic Sea Blue clan has worshiped Lord Hnálla since the ancient days of the Empire of the Gods-- the most noble of gods for the most noble of families.  Lord Hnálla  calls upon his worshipers to fulfill their place in society with dignity and to strive industriously against change and decay, both in a spiritual sense and in the physical world.  Kneeling before a statue of his twelfth aspect: Baján Ke'ún, "Guardian of the Imperium and Patron of the Armies," you scatter a handful of fresh white blossoms and flawless quartz crystals upon the altar.
		*set Dutiful %+20
		*set God  "Hnálla"
		*set Godhis "his"
		*set Godhe "he"
		*set Godhim "him"
		*set Clan  "Golden Sunburst"
		*set Lineage  "hiMaródla" 
		*set PrinceName  "Rereshqála"
		*set Prince  "Prince" 
		*set Legion  "Blue Peak"
		*set LegionType  "Heavy Infantry"
		*set LegionNum  26
		*set General  "Aruonmu hiSSanmirin"
		*set Hometown  "Jakálla"
		*goto pray
	#Lord Karakán, Lord of Glorious War and high general of Stability
		The hiBosúga lineage are a minority of Karakán worshipers within the largely Vimhúla-centric Red Sun clan.   This can sometimes create friction, but often the temples of the two war gods see politically eye-to-eye despite differing philosophies.   Karakán asks his soldiers to brave, but also just and restrained, as they battle to serve the State.  The statue of his twenty-ninth aspect: Faishán, "The Pinnacle of Victory" is a proud young woman leaning on a spear.  You gaze into her eyes and promise to capture and sacrifice an enemy soldier in her name using a silver dagger that you have bought specifically for the purpose.
		*set dutiful %+20
		*set diplomatic %-20
		*set God  "Karakán"
		*set Godhis "his"
		*set Godhe "he"
		*set Godhim "him"
		*set Clan  "Red Sun"
		*set Lineage  "hiBosúga"
		*set PrinceName  "Mirusíya"
		*set Prince  "Prince"
		*set Legion  "Lord of Red Devastation"
		*set LegionType  "Medium Infantry"
		*set LegionNum  18
		*Set General  "Mriyan hiKetkolel"
		*set Hometown  "Butrús"
		*goto pray
	#Lady Avánthe, Mistress of Heaven and the goddess of women and nature
		The hiChákkena lineage of the White Stone clan have always been devoted to Lady Avánthe.  The Mistress of Heaven seeks to create a tranquil and orderly world, which moves in harmonious cycles.  Her followers are tasked to travel gracefully through the stages of life, to seek justice and to protect women.  Standing at attention before the statue of her second aspect: Kátha, "The Warrior Maid," you sing a brave battle song before placing a single perfect piece of fruit upon the altar.
		*set dutiful %+20
		*set diplomatic %+20
		*set God  "Avánthe"
		*set Godhis "her"
		*set Godhe "she"
		*set Godhim "her"
		*set Clan  "White Stone"
		*set Lineage  "hiChákkena"
		*set PrinceName  "Ma'ín"
		*set Legion  "Translucent Emerald"
		*set LegionType  "Heavy Infantry"
		*set LegionNum  36
		*Set General  "Shrikomé hiTlashésha"
		*set Hometown  "Béy Sü"
		*goto pray
	#Lord Hrú'ü, the Dispenser of Calamities and supreme principal of Change
		The hiCháika lineage of the ancient and aristocratic Sea Blue clan has been worshiping Hrú'ü since before many other so-called noble clans even existed.  It is a paradox that a family devoted to the ideals of change has attained a timeless role as pillars of the state, but in truth it is by acknowledging that calamity is inevitable and riding the waves of change that you have survived the fall of Empires.  Hrú'ü teaches to avoid complacency and seek individual power and freedom.  You stand proudly before a statue of a great toad-like beast.  It is the  aspect Kaishmá, "Lord of the Deep Purple Dark."  Upon the altar you place a belt of braided purple silk and cloth of gold.
		*set dutiful %-20
		*set God  "Hrú'ü"
		*set Godhis "his"
		*set Godhe "he"
		*set Godhim "him"
		*set Clan  "Sea Blue"
		*set Lineage  "hiCháika" 
		*set PrinceName  "Rereshqála"
		*set Prince  "Prince" 
		*set Legion  "Blue Peak"
		*set LegionType  "Heavy Infantry"
		*set LegionNum  26
		*set Hometown  "Jakálla"
		*goto pray
	#Lord Vimhúla, the Power of Destruction and Red Ruin, Lord of Flame
		The hiShanuka lineage of the Red Sun clan will always be passionate and devoted followers of the Flame Cupped Within the Lamp.  Vimhúla demands that his soldiers be brave and fierce in battle.  He glories in destruction, pyromania, and pillaging, but these acts are reserved for defeated enemies.  On the altar before the statue of Vimhúla's fourth aspect: Dumúggash, "The Spirit of Battle," you sprinkle the ashes of your slave, Visán.  
		*set dutiful %-20
		*set diplomatic %-20
		*set God  "Vimhúla"
		*set Godhis "his"
		*set Godhe "he"
		*set Godhim "him"
		*set Clan  "Red Sun"
		*set Lineage  "hiShanúka"
		*set PrinceName  "Mirusíya"
		*set Prince  "Prince"
		*set Legion "Lord of Red Devastation"
		*set LegionType  "Medium Infantry"
		*set LegionNum  18
		*Set General  "Mriyan hiKetkolel"
		*set Hometown  "Butrús"
		*page_break
		Visán served your father as a retainer for years before being given to you as a present on the day you joined the Legion of the ${Legion}.  Over the years he had cared for your armor, listened to your thoughts, and kept your secrets; but had long suffered from old age and a rattling cough.  Knowing he would not survive the upcoming march, he asked permission to be immolated by the priests as an offering for your victory.
		*choice
			#Visán was useless to me as a slave. I was going to have him immolated soon anyway.  
				The old man was tied to a stake with another slave, and though at first he was brave you could see doubts begin to show as the fire was lit.  By the time the flames had begun to rise he was manfully trying not to scream.  But they all scream in the end, and his wails were music to Vimhúla's ears.
				*set diplomatic %-20
				*goto pray
			#Touched by the old retainer's gesture and nobility of spirit, I accepted his offer  and did everything I could to make his passing pleasant.
				From one of the priests you purchased a powerful cocktail of drugs, guaranteed to induce euphoria and numb pain.  With great ceremony Visán walked to the stake, and as the flames rose his voice could be heard singing a death song,  until finally he was overcome by heat and smoke.  You remember his passing with both sadness and pride.
				*goto pray
			#Though I knew it was wrong, I could not bear to see Visán burned, and convinced him to accompany me.
				Soon after this conversation Visán's cough worsened.  He passed away in comfort, carried in a palanquin and waited upon by your other servants while the legion marched.  His body was cremated, and you now place the ashes upon the altar along with some precious fire-opals which you hope will make up for your moment of weakness.
				*set noble %-10
				*set diplomatic %+30
				*goto pray
	#Lady Dlamélish, the Green Eyed Lady of Fleshly Joys and Mistress of Demons
		The hiVriyén lineage of the White Stone clan revels in the patronage of Lady Dlamélish.  The Green Eyed Lady is a mystical goddess of pleasure who encourages her followers to live in the moment and seek out new experiences.   As a soldier you do her honor whenever you feel the rush of battle or gaze triumphantly upon a new vista.  The statue of a beautiful and sensuous woman before you is her thirty-fourth aspect: Mrikáya, "She Who Takes Pleasure in Battle".  On the altar you pleasingly arrange three large green blossoms and several silver coins.
		*set dutiful %-20
		*set diplomatic %+20
		*set God  "Dlamélish"
		*set Godhis "her"
		*set Godhe "she"
		*set Godhim "her"
		*set Clan  "White Stone"
		*set Lineage  "hiVriyén"
		*set PrinceName  "Ma'ín"
		*set Legion  "Translucent Emerald"
		*set LegionType  "Heavy Infantry"
		*set LegionNum  36
		*Set General  "Shrikomé hiTlashésha"
		*set Hometown  "Béy Sü"
		*goto pray
		
		
*label pray
And what brings you to ${God}'s Temple?
*choice
	#I hope to lead my men well in the coming siege.
		*set noble %+10
		*if God = "Dlamélish"
			Your fickle and hedonistic goddess is not often asked to grant steadiness of nerves and mind, but you hope that the novelty of the request will appeal to her.
			*goto assassination
		*elseif God = "Karakán"
			This is a very appropriate prayer for this shrine, and you feel sure that Faishán will reward your responsible leadership with victory.
			*goto assassination
		*else
			Four hundred soldiers look to you for guidance.  It is a weighty responsibility, and you pray to do honor to your clan.
			*goto assassination
	#I want to find glory and promotion
			*set dutiful %-20
			*if God  = "Hrú'ü"
				The Lord of Confusion has always blessed your family with glory, and you ask him to bring calamity down upon your enemies; both within the armies you will face, and upon those in your own army with whom you will compete for notice.  It will still fall to you to grasp the opportunity when it comes.
				*goto assassination
			*else
				The military is one of the few methods of social advancement within the Tsolyáni Imperium; and a soldier who is good at his trade, respectful of his superiors, and liberal with bribes can rise far, especially with a little luck.  Hopefully this offering has brought you that luck.
				*goto assassination
	#I wish to return safely to my home and family when this is over
		You beseech ${God} to extend ${godhis} protection over you, promising more offerings to come if you make it home alive.
		 
		*if God = "Vimhúla"
			If the priests of the Flame Lord heard this prayer they would surely brand you a coward, but there is no option other than honesty when communing privately with your god, and you hope that if you fight well in his name Vimhúla will tolerate your imperfections.
			*set noble %-10
			*goto assassination
		*else
			Though few soldiers would admit it, many of them share this secret prayer.
			*goto assassination


*label assassination

As you finish praying the silence of the temple is disturbed by the faint scuffing of sandals upon stone.  You turn in time to see a woman, wearing the badge of an assassin's clan, raise a blowgun to her lips.  As you duck, a poisoned dart whistles by your ear to thunk into the altar.  You are alone in the small shrine and unarmored, though your _chlén_ hide sword leans against the altar.  (Metal is too rare on Tekumel to be of common use, and so soldiers fight with weapons cut from a tough hide which has been chemically treated to resemble soft bronze.)
*choice
	#I grab my _chlén_ hide sword and lunge for the woman in expert form.
		It is your deadliness in battle which has so impressed your superiors in the Legion of the ${Legion} and led to your rapid promotion to the rank of kási.  With the element of surprise wasted, the assassin is at a disadvantage and you press the attack.
		*set combat +40
		*page_break
		Though momentarily off balance the assassin displays the speed and trickery for which her kind are known, and a poisoned blade is soon at your throat.
		*choice
			#I fight defensively and whistle for two of my soldiers who are stationed outside.
				_Kásikoi_ are expected to be tactical thinkers as well as physically powerful, and you are no exception.  By focusing purely on defense you negate any difference in skill, and the assassin is soon flanked by your soldiers.  Realizing, too late, her position, she looks around for a route of escape.
				*set tactics +20
				*choice
					#As she turns to parry one of my soldiers I finish her with a single sword stroke.  Her death is a fair price for an attempt upon my life, but I make it quick.
						The assassin falls limply to the floor and lays motionless in a spreading pile of blood.
						*goto why
					#I motion for my soldiers to grab her.   I'm curious to know whether it's true that Assassins cannot be tortured into betraying their clients.
						*goto questioning
					#I lunge, stopping my sword inches from her throat.  "Do you yield?"
						*goto surrender
					*if God = "Karakán"
						#This must be the sacrifice Lord Karakán wants of me.  I pull out my silver dagger and plunge it quickly into her heart.
							*goto sacrifice
			#You must be mistaken.  She may be talented but I am one of the finest swordsmen in the empire.
				The look of victory in the assassin's eyes turn to surprise as you shift your sword from your left hand to the right, and begin to really put her through her paces.  Soon she is breathing heavily and clearly attempting to disengage.
				*set combat +20
				*choice
					#Fatigued, she is too slow to recover from a thrust and I finish her with a single sword stroke.  Her death is a fair price for an attempt upon my life, but I make it quick.
						The assassin falls limply to the floor and lays motionless in a spreading pile of blood.
						*goto why
					#I play with her as a cat plays with a mouse, making shallow cuts that weaken but to do not kill, until she is helpless at my feet.  I'm curious to know whether it's true that Assassins cannot be tortured into betraying their clients.
						*goto questioning
					#I lunge, stopping my sword inches from her throat.  "Do you yield?"
						*goto surrender
					*if God = "Karakán"
						#This must be the sacrifice Lord Karakán wants of me.  I pull out my silver dagger and plunge it quickly into her heart.
							*goto sacrifice
	#I cast the spell 'Hands of Kra the Mighty', and crush her, as one does a fly.
		Though you are not as talented as the mages of your legion's sorcerer corps, you studied the casting of spells in Temple School, attaining a low priestly rank.   You strike the ritual poses needed to bring forth a spell and the assassin's eyes widen in fear.  
		*set ritual +40
		*page_break
		A great force cracks the stone flagging as she leaps aside and throws a small bronze  dagger which lodges in your thigh.  It is suicide to cast spells while touching metal, and she charges you like a wild zrné beast, pressing the attack before you can remove the knife.
		*choice 
			#Though an accomplished spell caster and leader of men, I am no match for an assassin in close combat, so I fight defensively and whistle for two of my soldiers who are stationed outside.
				Kásikoi are expected to be tactical thinkers as well as personally formidable, and you are no exception.  You grab your chlén hide sword  and use it to parry while retreating.  By focusing purely on defense you negate any difference in skill, and the assassin is soon flanked by your soldiers.  Realizing, too late, her position, she looks around for a route of escape.
				*set tactics +20
				*choice
					#As she turns to parry one of my soldiers I finish her with a single sword stroke.  Her death is a fair price for an attempt upon my life, but I make it quick.
						The assassin falls limply to the floor and lays motionless in a spreading pile of blood.
						*goto why
					#I motion for my soldiers to grab her.   I'm curious to know whether it's true that Assassins cannot be tortured into betraying their clients.
						*goto questioning
					#I lunge, stopping my sword inches from her throat.  "Do you yield?"
						*goto surrender
					*if God = "Karakán"
						#This must be the sacrifice Lord Karakán wants of me.  I pull out my silver dagger and plunge it quickly into her heart.
							*goto sacrifice
			#I am as deadly with a sword as I am with my spells, and leap to meet her attack with a ferocious counter attack.
				The look of victory in the assassin's eyes turn to surprise as you grab your chlén hide sword and leap forward.  After a few exchanges, you boldly duck down and remove the bronze dagger.  Fearing your spells the assassin backs away.
				*set combat +20
				*choice
					#She is too tired now to dodge my spell which crushes her with terrifying force.  Her death is a fair price for an attempt upon my life, but I make it quick.
						There is a loud crack as the assassin's head hits the floor.
						*goto why
					#With careful finesse I use my spell to pin her gently to the stone floor. I'm curious to know whether it's true that Assassins cannot be tortured into betraying their clients.
						*goto questioning
					#I once more strike the poses needed to cast spells and summon forth a ball of flame.  "Do you yield?"
						*goto surrender
					*if God = "Karakán"
						#This must be the sacrifice Lord Karakán wants of me.  I pin her to the floor with my spell and plunge my silver dagger into her heart.
							*goto sacrifice
	#I focus my psychic energies and time slows around me.  Picking up my chlén hide sword I advance.
		While not a ritual spell caster, you have innate psychic talents which were honed in Temple School.  You harness these now and move toward the assassin like a bolt of Lord Karakán's lightning.  
		*set psychic +40
		*page_break
		Though momentarily off balance, the assassin displays the speed and trickery for which her kind are known, and a poisoned blade is soon at your throat.
		*choice
			#I fight defensively and whistle for two of my soldiers who are stationed outside.
				Kásikoi are expected to be tactical thinkers as well as personally formidable, and you are no exception.  By focusing purely on defense you negate any difference in skill, and the assassin is soon flanked by your soldiers.  Realizing, too late, her position, she looks around for a route of escape.
				*set tactics +20
				*choice
					#As she turns to parry one of my soldiers I finish her with a single sword stroke.  Her death is a fair price for an attempt upon my life, but I make it quick.
						The assassin falls limply to the floor and lays motionless in a spreading pile of blood.
						*goto why
					#I motion for my soldiers to grab her.   I'm curious to know whether it's true that Assassins cannot be tortured into betraying their clients.
						*goto questioning
					#I lunge, stopping my sword inches from her throat.  "Do you yield?"
						*goto surrender
					*if God = "Karakán"
						#This must be the sacrifice Lord Karakán wants of me.  I pull out my silver dagger and plunge it quickly into her heart.
							*goto sacrifice
			#You must be mistaken.  She may be talented, but I am one of the finest psychic warriors in the empire.
				The look of victory in the assassin's eyes turns to surprise as you shift your sword from your left hand to the right, and begin to really put her through her paces.  Soon she is breathing heavily and clearly attempting to disengage.
				*set combat +20
				*choice
					#After a furious exchange of blows I step back and release a deadly bolt of telekinetic force.  Her death is a fair price for an attempt upon my life, but I make it quick.
						The assassin falls limply to the floor and lays motionless, like a doll.
						*goto why
					#I play with her as a cat plays with a mouse, making shallow cuts that weaken but to do not kill, until she is helpless at my feet.  I'm curious to know whether it's true that Assassins cannot be tortured into betraying their clients.
						*goto questioning
					#I lunge, stopping my sword inches from her throat.  "Do you yield?"
						*goto surrender
					*if God = "Karakán"
						#This must be the sacrifice Lord Karakán wants of me.  I pull out my silver dagger and plunge it quickly into her heart.
							*goto sacrifice
	#I whistle for two of my soldiers who are stationed outside.
		Kásikoi are expected above all to be tactical thinkers, and you are no exception.  You calculate that if you can hold her off for a few exchanges your men will be able to flank her.
		*set tactics +40
		*choice
			#I grab my chlén hide sword and prepare to defend myself.
				Though more a commander of men than a fighter, you are still a soldier of the ${legionnum} and a match for this assassin, especially when time is on your side.  You skillfully parry and retreat, until your soldiers arrive.  Realizing, too late, her position, she looks around for a route of escape.
				*set combat +20
				*choice
					#As she turns to parry one of my soldiers I finish her with a single sword stroke.  Her death is a fair price for an attempt upon my life, but I make it quick.
						The assassin falls limply to the floor and lays motionless in a spreading pile of blood.
						*goto why
					#I motion for my soldiers to grab her.   I'm curious to know whether it's true that Assassins cannot be tortured into betraying their clients.
						*goto questioning
					#I lunge, stopping my sword inches from her throat.  "Do you yield?"
						*goto surrender
					*if God = "Karakán"
						#This must be the sacrifice Lord Karakán wants of me.  I pull out my silver dagger and plunge it quickly into her heart.
							*goto sacrifice
			#Calling upon my brief training as a ritual spell caster, I summon a magical shield.
				Though only of minor talent, you studied the casting of spells in Temple School, attaining a low priestly rank.   By chanting and doing a brief ritual dance you summon a globe of Guarding around yourself.  You cannot attack from within it, but neither can the assassin get to you, except by pushing slowly through the defense.  She is still trying to crack this strange egg when your soldiers arrive.  Realizing, too late, her position, she looks around for a route of escape.
				*set ritual +20
				*choice
					#As she begins to fight my soldiers I drop the spell of Guarding and, picking up my chlén hide sword, finish her with a single stroke.  Her death is a fair price for an attempt upon my life, but I make it quick.
						The assassin falls limply to the floor and lays motionless in a spreading pile of blood.
						*goto why
					#I motion for my soldiers to grab her.   I'm curious to know whether it's true that Assassins cannot be tortured into betraying their clients.
						*goto questioning
					#I once more strike the poses needed to cast spells and summon forth a ball of flame.  "Do you yield?"
						*goto surrender
					*if God = "Karakán"
						#This must be the sacrifice Lord Karakán wants of me.  I pull out my silver dagger and plunge it quickly into her heart.
							*goto sacrifice
			#Focusing my psychic energies, I attempt to seize control of her mind.
				While not a ritual spell caster, you have innate psychic talents which were honed in Temple School.  Using the spell of Domination, you attempt to move the assassin's body as a puppeteer directs a puppet.  She is strong willed, and fights you off, but doing so takes all her concentration, and she can muster only the weakest defense against your soldiers when they arrive.
				*set psychic +20
				*choice
					#As she turns to parry one of my soldiers I grab up my chlén hide sword and finish her with a single sword stroke.  Her death is a fair price for an attempt upon my life, but I make it quick.
						The assassin falls limply to the floor and lays motionless in a spreading pile of blood.
						*goto why
					#I motion for my soldiers to grab her.   I'm curious to know whether it's true that Assassins cannot be tortured into betraying their clients.
						*goto questioning
					#I pick up my chlén hide sword and hold it to her throat.  "Do you yield?"
						*goto surrender
					*if God = "Karakán"
						#This must be the sacrifice Lord Karakán wants of me.  I pull out my silver dagger and plunge it quickly into her heart.
							*label sacrifice
							It is exactly the sort of quick and merciful sacrifice the god prefers, and an assassin is a worthy foe.  
							*if (psychic > 1) or (ritual > 1)
								Though normally casting spells or using psychic powers while carrying metal is suicidal, ritual daggers are excepted through the powers of the gods.
							As her heart's blood dampens your hand you are sure your prayer will be granted.	
							*set noble %+10
							*goto why	

*label surrender
The assassin looks into your eyes, showing no fear.  "If you let me live I promise my clan will return the payment and not make another attempt upon you."
*choice
	#I let her go.
		She bows deeply to you and walks from the shrine.  Assassination is legal in Tsolyánu, so no one stops her.  It seems anticlimactic somehow.
		*set diplomatic %+15
		*if God = "Avánthe"
			*set noble %+10
		*if God = "Vimhúla"
			*set noble %-10
		*goto why
	#I have changed my mind.  She cannot be left alive.
		*if (ritual>30) and ((combat >30) or (tactics >50))
			The assassin is engulfed in a torrent of flame.
			*goto why
		*else
			You execute the young woman with a single stroke to the neck.  She falls limply to the floor and lays motionless in a spreading pile of blood.
			*goto why							

*label questioning
*if God = "Vimhúla" 
	*set noble %+10
*if God = "Hrú'ü" 
	*set noble %+10
*if God = "Avánthe" 
	*set noble %-10
*if God = "Hnálla"
	*set noble %-10
*set diplomatic %-10
"Who sent you?"  
				
The assassin's face remains blank
*if ((psychic > 10) and (combat > 30)) or (combat > 50)
	as she falls to her knees weak with blood loss, 
*if ((ritual > 30) and (combat > 30))
	as she is crushed beneath your spell, 
*if (tactics >30)
	as she is grabbed, 
a picture of perfect stillness.  It is clear she intends to die with dignity, and silence. 
*choice
	#So it's true then?  Well I know who her employer is anyway.  I give her a merciful end.
		The woman gives you a look of weary gratitude, and then the light in her eyes is extinguished.
		*goto why
	#It's a shame intentions don't always equal success.
		You begin to torture the woman, but though she cries out to her god, Lord Ksárul, for deliverance, she does not speak.
		 
		In the end she manages to end her life with a quick slap to her neck, resembling the swatting of a mosquito, which leaves behind a poisoned dart.  
		*if tactics >30
			The soldier who had let her arm free in his blanching distraction is stabbed as well, with snake-like swiftness.  He collapses to the stones, foaming at the mouth.
		 
		She passes from this life having not betrayed her clan or her employer.
		*goto why
	
*label why
*page_break
So, why would someone send an assassin after you anyway?
*choice
	#I killed a rival for the sake of my beloved.
		Jealousy is viewed as ignoble within Tsolyáni society, but that does not keep young people from dueling over perceived slights from their competition in affairs of the heart when passions run high. In your case the duel ended in death, and left a grieving mother fixated upon your destruction.  What effect this will have upon your destiny is yet to be seen.
		*set assassination  1
		*finish
	#The weak envy the strong.  I don't have time to enumerate every grievance brought against me by lesser men.
		The shámtla paid to the family of some peasant or medium clan bureaucrat killed over a matter of principle is almost pocket change to one of your station, which allows you to keep your inferiors in line.  Unfortunately, some families cannot let the matter drop and insist on hiring assassins to pursue their grievance for them when the courts have failed.  It is quite annoying, but you soon put the matter out of your mind.
		*set assassination  2
		*finish
	#I prevented an injustice
		Though assassins are only supposed to take commissions which redress ignoble action, it is a truism that all men are corruptible.  Having failed to gain his revenge in the courts, your powerful enemy uses his fortune to send greedy assassins after you on the flimsiest of pretexts.  Thus far you have been lucky in surviving such attempts.
		*set assassination  3
		*finish
	#I killed a man in anger, and deeply regret it. 
		The offense was tried in military court, and with your elevated status and the situation taken into consideration, you were given a light punishment.  Not knowing the regret you carry in your heart for that red deed, his family saw only a murderer going unpunished, and have spent a small fortune in pursuit of vengeance.  You are unsure how to handle the situation.
		*set assassination  4
		*finish